options nocenter ;
title1 h=2 j=l "Analyse factorielle des correspondaces multiples (X1 X2 X3)*(X1 X2 X3)";
title2 h=1 j=l "Données MM";
title3 ; * une ligne blanche pour séparer les titres ;
footnote1 h=2 j=l 'Master Marketing Paris-Dauphine';
footnote2 h=1 j=l 'Source : Analyse des données appliquée au marketing ' j=r '2007 (c) Pierre Desmet';
goptions reset=symbol ;

data in;
	input (ID x1-X4 sup) ($) ; * les valeurs sont les modalités ;
	* elles sont transformées en tableau disjonctif complet ;
	* I1 1 0 0 1 0 0 1 0 0 0 1  1 0  pour la première ligne ;
cards ;
I1 A1 B2 C3 D4 Out
I2 A2 B2 C2 D2 In
I3 A1 B1 C2 D3 Out
I4 A2 B1 C1 D4 Out
I5 A2 B2 C1 D1 In
I6 A1 B1 C3 D1 In
I7 A2 B2 C2 D1 Out
;
proc print  data=in ;
title4 "1- Lecture ";


*************** analyse des correspondances des variables ***************;
proc corresp  data=in mca obs all outc=corr;
	tables x1--x4 sup; * lister simplement les variables ;
	supplementary sup;
title4 "Analyse des correspondances multiples ";

* proc print data=corr;
* profils ligne *************; 

data work ; 
	set corr;
	if _TYPE_='VAR';
		X=dim1 ;
		Y=dim2;
		text=_name_; 
		size=2;
		xsys='2';
		ysys='2';
		Label 	Y='Dim 2'
				X='Dim 1';
		keep X Y Xsys Ysys text size  ;
		run;
Title4 'premier plan factoriel';
Proc gplot data=work;
	symbol1 V=none i=none;
	plot Y*X=1 / annotate=work Frame Href=0 Vref=0;
	run;
* avec les variabkles supplémentaires ;
data work ; 
	set corr;
	if _TYPE_='VAR' or _TYPE_='SUPVAR';
	if _TYPE_='VAR' 	then color='BLUE';
	if _TYPE_='SUPVAR' 	then color='RED';
		X=dim1 ;
		Y=dim2;
		text=_name_ ; * variable d'identification ;
		size=1;
		xsys='2';
		ysys='2';
		Label 	Y='Dim 2'
				X='Dim 1';
		keep X Y Xsys Ysys text size color ;
		run;
Title4 'premier plan factoriel';
Proc gplot data=work;
	symbol1 V=none i=none;
	plot Y*X=1 / annotate=work Frame Href=0 Vref=0;
	run;