/* PROG 1 : Opération IPhone  */
*DEBUT DE MON PROGRAMME;
************************;
options formdlim="-";
TITLE    H=3    J=L "Opération IPhone";
TITLE1    H=2    J=L "Tests paramétriques";
TITLE3    H=3        ;

FOOTNOTE1 H=2 	J=L "Master Marketing Paris-Dauphine";
FOOTNOTE2 H=1 	J=L "SOURCE : Analyse des données appliquée au marketing" J=R "(c)2007  Pierre DESMET";

DATA IN ;
	INPUT Q01-Q11 Q12 $;

IF Q12="H" 			THEN Q13=0;
	ELSE IF Q12="F" THEN Q13=1;
		ELSE 			 Q13=.;

IF Q12="H" 			THEN Q14=-1;
	ELSE IF Q12="F" THEN Q14=1;
		ELSE 			 Q14=.;

		Q05=Q05/10;
* création d'une intention d'achat binaire si Q11 = 3 ou plus;
IF Q11=>3 then IA=1; 
	else IA=0;

* création d'une variable ecran_tactile ;
IF Q07=3 then ecran_tactile=1;
	else ecran_tactile = 0;

LABEL
	Q01="Nh heures de forfait telephone mobile"
	Q02="Budget mensuel telephone mobile"
	Q03="Abonnement MMS"
	Q04="Si oui, combien envoyes par mois"
	Q05="Nb heures par jour sur internet"
	Q06="Satisfaction mobile actuel"
	Q07="Quelle interface preferez vous : clavier, stylet, ecran tactile ?" 
	Q08="CHOIX2"
	Q09="CHOIX3"
	Q10="Combien seriez vous pret a payer pour un Iphone"
	Q11="Intention d’achat de l’Iphone à 429 euros (1 à 7)"
	Q12="GENRE"
	IA="Intention d'achat binaire"
	ecran_tactile="Interface préférée = écran tactile"
	Q13='Dummy(0,1)'
	Q14='Auxiliaire (-1,+1)';

CARDS;
4 35 1 0 15 2 1 3 2 200 1 F
3 50 0 0 15 3 1 3 2 200 3 F
4 45 0 0 20 3 1 3 2 50 1 H
4 55 1 3 20 2 2 3 1 350 6 F
4 55 0 0 20 5 1 2 3 200 1 F
4 60 1 1 40 5 1 3 2 150 1 H
3 40 0 0 20 6 2 3 1 50 2 H
4 50 0 0 30 6 1 3 2 50 1 F
2 40 0 0 20 7 1 2 3 0 1 F
0 20 0 0 30 1 1 3 2 10 1 H
3 45 0 0 10 7 1 2 3 70 1 F
2 28 0 0 10 5 1 2 3 50 1 F
1 15 0 0 10 5 1 2 3 50 1 F
1 25 0 0 10 6 1 3 2 150 1 F
0 30 0 0 30 3 3 1 2 200 1 F
4 50 1 3 10 5 1 3 2 250 3 H
4 48 0 0 30 5 1 3 2 200 2 F
2 35 1 0 20 5 1 3 2 100 3 F
5 50 0 0 15 6 1 3 2 250 3 F
3 55 0 0 20 5 2 1 3 150 1 F
4 60 1 0 20 6 1 2 3 150 1 F
3 50 0 0 10 5 1 3 2 150 1 F
3 35 0 0 20 6 3 1 2 50 1 F
2 18 0 0 15 3 3 1 2 200 1 F
2 35 0 0 15 6 1 3 2 75 1 F
4 50 1 1 20 6 1 3 2 10 1 F
4 40 0 0 30 7 2 3 1 300 5 H
;
PROC FORMAT;
	VALUE MMSFMT 	0="NON" 
					1="OUI";
	VALUE GENREFMT 	0="HOMME" 
					1="FEMME";
	VALUE FMTA 	1="TRES INSATISFAIT"
				2="INSATISFAIT"
				3="PLUTOT INSATISFAIT"
				4="NI SATISFAIT NI INSATISFAIT"
				5="PLUTOT SATISFAIT"
				6="SATISFAIT"
				7="TRES SATISFAIT";
	VALUE FMTB 	1-3="INSATISFAIT" 
				4="NE SAIT PAS" 
				5-7="SATISFAIT";
	VALUE FORFAIT4FMT  0-3="Moins de 4 heures" 4-High="4 H et plus";

title2 ; * annule le title2 précédent;

**********************************************************;
* test de la normalité ;
**********************************************************;

Proc univariate data=in  plot normal ;
	var q02 ;
	histogram / cfill=red normal midpoints= 0 to 100 by 10;
	qqplot  / normal(mu=est sigma=est color=red);
Proc univariate data=in  plot normal ;
	var q01;
	histogram / cfill=red normal midpoints= 0 to 10 by 1;
	qqplot  / normal(mu=est sigma=est color=red);
Proc univariate data=in  plot normal ;
	var q05;
	histogram / cfill=red normal midpoints= 0 to 6 by 1;
	qqplot  / normal(mu=est sigma=est color=red);

**********************************************************;
* test des différences de budget selon le sexe ;
**********************************************************;
proc sort data=in ;
	by q13;
proc gchart data=in ;
	vbar Q13 / frame discrete  group=q13 subgroup=q01 type=percent g100;
	format q13 genrefmt. ;
	run;
title3 'PROC GCHART : tuyaux ';

proc boxplot data=in; 
  plot q02*q13 / boxstyle=schematic boxwidth=10;
  format q13 genrefmt.;
run;
title3 'PROC box plot ';
proc tabulate data=in;
	class Q13 ;
		var q02;
		table (q13 all), q02* (N mean std ) ;
		format q13 genrefmt.;
title3 'PROC TABULATE : moyenne et écart-type ';

proc ttest ;
	class q12 ; 
	var Q02;
title3 'PROC TTEST uniquement pour une variable à 2 modalités ';

proc anova  ;
	class q12;
	model q02= q12  ;
	means      q12 /scheffe alpha=0.05 CLDIFF LINES;
title3 'PROC ANOVA dans une expérimentation (nb modalités quelconque) ';

proc reg data=in;
	model q02 = q13;
title3 'PROC REG Regression pour des données naturelles (variables auxiliaires à créer) ';
title4 'Auxiliaire : codage 0-1 ';
proc reg data=in;
	model q02 = q14;
title4 'Auxiliaire : codage -1 +1 ';

proc glm ;
	class q12;
	model q02= q12 / solution;
	means      q12 /scheffe alpha=0.05 CLDIFF LINES;
	CONTRAST 'Différence Homme-Femme'  q12  -1  1; * la somme des coefficients du contraste doit faire 0;
title3 'PROC GLM modèle linéaire général pour tout type de données';

proc GLM  ;
	class q12;
	model q02= q12 Q01 / solution ;
	means      q12 /scheffe alpha=0.05 CLDIFF LINES;
title3 'PROC GLM pour une ANCOVA dans une expérimentation, variables continue et discrète ';