options nocenter ;
title1 h=3 j=l "CLUSTER - TYPOLOGIE Hiérarchique";
title2 h=2 j=l "Données MM";
title3 ; * une ligne blanche pour séparer les titres ;
footnote1 h=2 j=l 'Master Marketing Paris-Dauphine';
footnote2 h=1 j=l 'Source : Analyse des données appliquée au marketing ' j=r '2007 (c) Pierre Desmet';

data in;
	input q1-q4 type @@ ; * @@ indique que les variables sont en continu, les individus un derrière l'autre ;
	i=_N_ ; 					* création d'un numéro automatique dans i (car _N_ existe dans le système) ;

cards ;
 50 33 14 02 1 64 28 56 22 3 65 28 46 15 2
 67 31 56 24 3 63 28 51 15 3 46 34 14 03 1
 69 31 51 23 3 62 22 45 15 2 59 32 48 18 2 
 46 36 10 02 1 61 30 46 14 2 60 27 51 16 2
 65 30 52 20 3 56 25 39 11 2 63 30 55 18 3
 58 27 51 19 3 68 32 59 23 3 51 33 17 05 1
 57 28 45 13 2 62 34 54 23 3 77 38 67 22 3
 63 33 47 16 2 67 33 57 25 3 76 30 66 21 3
 49 31 15 02 1 77 26 69 23 3 60 22 50 15 3
 54 39 17 04 1 66 29 46 13 2 52 27 39 14 2
 60 34 45 16 2 50 34 15 02 1 44 29 14 02 1
 50 20 35 10 2 55 24 37 10 2 58 27 39 12 2
 47 32 13 02 1 46 31 15 02 1 51 34 15 02 1
 50 35 13 03 1 49 31 15 01 1 67 31 47 15 2
 54 37 15 02 1 56 30 41 13 2 63 25 49 15 2
 61 28 47 12 2 64 29 43 13 2 54 39 13 04 1
 51 35 14 03 1 45 23 13 03 1 51 37 15 04 1
 52 35 15 02 1 53 37 15 02 1 67 30 50 17 2
 63 33 60 25 3 58 28 51 24 3 57 25 50 20 3 
 68 30 55 21 3 64 27 53 19 3 65 32 51 20 3
;

************** proc cluster ********************;
ODS output ClusterHistory=data_history;			* ODS va permettre de sortir des graphiques des statistiques ;
proc cluster data=in 
			method=ward 
			simple pseudo rsquare ccc
			outtree=data_tree standard
			print=8 ; 	* ajouter standard pour standardiser les variables ;
			;
	var q2-q3;			* <<<<<<= mettre ici vos variables ;
	copy type;			* permet de copier dans le tableau une variable non utilisée dans la typo mais qui peut servir ensuite ;
	Run;
ODS output close;								* ferme ODS ;
title4 "1- Typologie hiérarchique (variables non standardisées)";

proc tree data=data_tree 
			horizontal 
			out=data_type Nclusters=3  ;* un tableau "data_type" avec 3 clusters sera constitué ;			
			copy q2-q3 type;			* copier dans le tableau data_type les variables q1 à q4 et type;

title4 "2- Dendrogramme";
run;

proc gplot data=data_history ;
	symbol1 i=join v=dot ;
	plot SemipartialRSq*NumberOfClusters RSquared*NumberOfClusters PseudoF*NumberOfClusters PseudoTSq*NumberOfClusters CubicClusCrit*NumberOfClusters;
title4 "3- Statistiques pour le nombre de groupes";
run;

proc gplot data= data_type;
	symbol1 i=none v=dot ;
	symbol2 i=none v=triangle ;
	symbol3 i=none v=square ;
	plot q3*q2=cluster;
title4 "4- Graphique plot des types";
	run ;