/* PROG 1 : Opération IPhone  */
*DEBUT DE MON PROGRAMME;
************************;
TITLE1    H=3    J=L "Opération IPhone";
TITLE2    H=2    J=L "Sorties graphiques GPLOT";
TITLE3   ;

FOOTNOTE1 H=2 	J=L "Master Marketing Paris-Dauphine";
FOOTNOTE2 H=1 	J=L "SOURCE : 2007 ANALYSE DES DONNEES MARKETING" J=R "(c) Pierre DESMET";

* goptions  reset=all ; * remise à jour des options de gplot/gchart ;

DATA IN ;
INPUT Q01-Q11 Q12 $;

IF Q12="H" 			THEN Q13=0;
	ELSE IF Q12="F" THEN Q13=1;
		ELSE 			 Q13=.;

* création d'une intention d'achat binaire si Q11 = 3 ou plus;
IF Q11=>3 then IA=1; 
	else IA=0;

* création d'une variable ecran_tactile ;
IF Q07=3 then ecran_tactile=1;
	else ecran_tactile = 0;

LABEL
	Q01="Nh heures de forfait telephone mobile"
	Q02="Budget mensuel telephone mobile"
	Q03="Abonnement MMS"
	Q04="Si oui, combien envoyes par mois"
	Q05="Nb heures par jour sur internet"
	Q06="Satisfaction mobile actuel"
	Q07="Quelle interface preferez vous : clavier, stylet, ecran tactile ?" 
	Q08="CHOIX2"
	Q09="CHOIX3"
	Q10="Combien seriez vous pret a payer pour un Iphone"
	Q11="Intention d’achat de l’Iphone à 429 euros (1 à 7)"
	Q12="GENRE"
	IA="Intention d'achat binaire"
	ecran_tactile="Interface préférée = écran tactile";

CARDS;
4 35 1 0 15 2 1 3 2 200 1 F
3 50 0 0 15 3 1 3 2 200 3 F
4 45 0 0 20 3 1 3 2 50 1 H
4 55 1 3 20 2 2 3 1 350 6 F
4 55 0 0 20 5 1 2 3 200 1 F
4 60 1 1 40 5 1 3 2 150 1 H
3 40 0 0 20 6 2 3 1 50 2 H
4 50 0 0 30 6 1 3 2 50 1 F
2 40 0 0 20 7 1 2 3 0 1 F
0 20 0 0 30 1 1 3 2 10 1 H
3 45 0 0 1 7 1 2 3 70 1 F
2 28 0 0 10 5 1 2 3 50 1 F
1 15 0 0 10 5 1 2 3 50 1 F
1 25 0 0 10 6 1 3 2 150 1 F
0 30 0 0 30 3 3 1 2 200 1 F
4 50 1 3 10 5 1 3 2 250 3 H
4 48 0 0 30 5 1 3 2 200 2 F
2 35 1 0 20 5 1 3 2 100 3 F
12 50 0 0 15 6 1 3 2 250 3 F
3 55 0 0 20 5 2 1 3 150 1 F
4 60 1 0 20 6 1 2 3 150 1 F
3 50 0 0 10 5 1 3 2 150 1 F
3 35 0 0 20 6 3 1 2 50 1 F
2 18 0 0 15 3 3 1 2 200 1 F
2 35 0 0 15 6 1 3 2 75 1 F
4 50 1 1 20 6 1 3 2 10 1 F
4 40 0 0 30 7 2 3 1 300 5 H
;
PROC FORMAT;
	VALUE MMSFMT 	0="NON" 
					1="OUI";
	VALUE GENREFMT 	0="HOMME" 
					1="FEMME";
	VALUE FMTA 	1="TRES INSATISFAIT"
				2="INSATISFAIT"
				3="PLUTOT INSATISFAIT"
				4="NI SATISFAIT NI INSATISFAIT"
				5="PLUTOT SATISFAIT"
				6="SATISFAIT"
				7="TRES SATISFAIT";
	VALUE FMTB 	1-3="INSATISFAIT" 
				4="NE SAIT PAS" 
				5-7="SATISFAIT";
	VALUE FORFAIT4FMT  0-3="Moins de 4 heures" 4-High="4 H et plus";


axis1 label=('Effectifs');

axis3 label=('%') 
		order=(0 to 100 by 10);

TITLE4    H=2    J=L "GCHART percent";
PROC GCHART data=in;
	VBAR Q10 / type =percent midpoints = 0, 50, 100, 150, 200, 250, 300, 350  ;
TITLE4    H=2    J=L "GCHART cpercent  (cumul)";
PROC GCHART data=in;
	VBAR Q10 / type =cpercent midpoints = 0, 50, 100, 150, 200, 250, 300, 350 ;
run;

axis2 label=none;
axis4 length=4cm;
proc Gchart data=in ;
	HBAR Q12 / noaxis subgroup=Q03 raxis=axis2 gaxis=axis4 sumvar=Q01 nostats ;
run;

*************************************************;
* Camembert ;
* chaque part correspond à une modalité du genre ;
* la taille de la portion correspond à l'effectif ;
*************************************************;


TITLE4    H=2    J=L "GCHART Camembert";
pattern1 color=gray value=solid ;       /* homme     */  
pattern2 color=lime;        			/* femme     */
/*autres couleurs :  blue green black cyan lipk lime red ...*/ 
ods rtf body="D:/Travail/Cours/MS_ADD07/pie.rtf" ; * sortie d'un fichier rtf ou pdf;
PROC GCHART data=in;
	pie  Q03/ discrete type=percent
				other=5
                  group=Q13
				  clockwise
                  slice=inside
					value=arrow ;
* slice inside /outside : texte et % dedans ou dehors ;
* value= arrow met le % en dehors avec une flêche ;
	format q13 genrefmt. q03 mmsfmt.;
run;
ODS rtf close ; 
*************************************************;
* histogramme barres horizontales HBAR;
* chaque barre correspond à une modalité du genre ;
* avec une variable calculée : la moyenne de Q01 ;
*************************************************;
PROC GCHART data=in;
	hbar Q13 / discrete sumvar=Q01 type=mean; 
	vbar Q13 / discrete sumvar=Q01 type=mean; 
run;

*================================ avec GPLOT ===============================;