* ===================================================================;
* Analyse sensorielle 												=;
* EPREUVES DISCRIMINATIVES : Triangulaire, duo-trio, 2 sur 5        =;
* Pierre DESMET Janvier 2012 										=;
* ===================================================================;
footnote1 h=1  j=l "Université Paris-Dauphine" j=r "(c) DESMET Pierre, 2012";

ODS rtf ;


********************************************************************;
* D1. Epreuve triangulaire ;
********************************************************************;
* proposition de 3 produits dont 2 identiques : choix d'un produit  ;
********************************************************************;
	/* prob théorique à calculer selon le nombre de produits */
	/* à prendre en unilatéral d'où 10%						 */

data in ;
	input effectif reponse;
	x=0 ; freq = reponse ;output ;			/* bonnes réponses    */
	x=1 ; freq = effectif-reponse ; output; /* mauvaises réponses */
cards; 
36 24
;
proc format ;
value xfmt 0="Réponses correctes"  1="Réponses fausses" ;
run ;
Title1 j=l "Discriminatif : Epreuve triangulaire de différence NF V 09-001" ;
Title2 j=l "Test binomial Unilatéral, p=1/3";
Title3 j=l "LIRE : unilatéral" ;
Title4 H=3 "Examinez ces trois produits de gauche à droite. Indiquez le numéro de celui que vous trouvez différent";

proc freq data = in;
	weight freq ;
	tables x / binomial(p=0.333333) alpha= .05;
	exact binomial;
	format x xfmt. ; 
run ;

Title1 j=l "Table 1: valeurs critiques Kc Test Triangulaire" j=r "Test binomial Unilatéral, p=1/3";
Title2 "Risque à 5% ";
Title3 ""; title4 ""; title5 "";

data table1 ;
	retain p0 ;
	p0=1;
	do nb_juges = 5 to 30 ;
		do nb_succes= 3 to nb_juges by 1;
			nb_s5 = nb_succes+1 ;
			probabilite= 1- probbnml(0.3333, nb_juges, nb_succes);
			if p0>0.04999999 and probabilite<0.050000001 then output ;
			p0 =probabilite ;
 		end;
	end ;

proc tabulate data=table1 ;
	class nb_juges ;
	var nb_s5 probabilite;
	table nb_juges, nb_s5*mean*F=6.0 probabilite*mean*F=8.5 / rts= 15;
run;

Title1 j=l "Table 2: valeurs critiques Kc Test Triangulaire" j=r "Test binomial Unilatéral, p=1/3";
Title2 "Risque à 1% ";
data table1 ;
	retain p0 ;
	p0=1;
	do nb_juges = 5 to 30 ;
		do nb_succes= 3 to nb_juges by 1;
			nb_s1 = nb_succes+1 ;
			probabilite= 1- probbnml(0.3333, nb_juges, nb_succes);
			if p0>0.00999999 and probabilite<0.010000001 then output ;
			p0 =probabilite ;
 		end;
	end ;

proc tabulate data=table1 ;
	class nb_juges ;
	var nb_s1 probabilite;
	table nb_juges, nb_s1*mean*F=6.0 probabilite*mean*F=8.5 / rts= 15;
run;



********************************************************************;
* D2. Duo-Trio ;
********************************************************************;
* Choix d'un produit identique au témoin parmi 2  ;
********************************************************************;
	/* prob théorique à calculer selon le nombre de produits */
	/* à prendre en unilatéral d'où 10%						 */
data in ;
	input effectif reponse;
	x=0 ; freq = reponse ;output ;			/* bonnes réponses    */
	x=1 ; freq = effectif-reponse ; output; /* mauvaises réponses */
cards; 
36 24
;
proc format ;
value xfmt 0="Réponses correctes"  1="Réponses fausses" ;
run ;
Title1 j=l "Discriminatif : Epreuve Duo-Trio NF ISO 10399";
Title2 j=l "Test binomial Unilatéral, p=1/2";
Title3 j=l "LIRE : unilatéral" ;
Title4 "Examinez ces trois produits de gauche à droite. Le premier est le témoin. L'un des deux autres est différent du témoin";
Title5 "Indiquez le numéro de celui que vous trouvez différent";

proc freq data = in;
	weight freq ;
	tables x / binomial(p=0.5) alpha= .05;
	exact binomial;
	format x xfmt. ; 
run ;

********************************************************************;
* D3. 2 sur 5 ;
********************************************************************;
* grouper 2 produits parmi 5 (2 A + 3 B)                            ;
********************************************************************;
	/* prob théorique à calculer selon le nombre de produits */
	/* à prendre 5% en unilatéral d'où 10%					 */
data in ;
	input effectif reponse;
	x=0 ; freq = reponse ;output ;			/* bonnes réponses    */
	x=1 ; freq = effectif-reponse ; output; /* mauvaises réponses */
cards; 
36 24
;
proc format ;
value xfmt 0="Réponses fausses" 1="Réponses correctes" ;
run ;
Title1 j=l "Discriminatif : Epreuve 2 sur 5  NF V 09-001";
Title2 j=l "Test binomial Unilatéral, p=1/10";
Title3 j=l "LIRE : unilatéral" ;
Title4 "Examinez ces 5 échantillons de produits de gauche à droite.";
Title5 "Reconstituez les deux groupes d'échantillons en entourant les 2 produits du même type";
/* 20 jeux de 5 échantillons chacun (2+3). 1 par sujet (pas de répétition) */
proc freq data = in;
	weight freq ;
	tables x / binomial(p=0.10)  alpha= .05;
	exact binomial;
	format x xfmt. ;
run ;